윈도우10 제품키 확인 방법 윈도우 시디키 정보 확인하기

윈도우10 제품키 확인 방법을 알려드리겠습니다. 윈도우 컴퓨터에서 MS 계정을 사용하고 싶지 않다면 오프라인 계정으로 윈도우를 설치하면 됩니다. 오프라인 계정으로 윈도우를 설치하려면 윈도우 제품키 또는 시리얼 넘버를 알고 있어야 합니다.

윈도우10 제품키 확인

제품키는 윈도우 컴퓨터 내에서 확인할 수 있습니다. 윈도우10 제품키 확인 방법은 다음과 같습니다.

 

윈도우 시디키 정보 확인

윈도우 설치 시 제품키를 입력해야 오프라인 계정으로 윈도우를 사용할 수 있습니다. 이를 위해선 윈도우 계정 로그인 하는 대신 제품키를 입력하여 정품 인증을 받아야 합니다.

윈도우 라이선스 정보는 MS 계정에 귀속 됩니다. 이에 윈도우를 설치한 후 MS 계정으로 로그인하면 정품 인증이 완료됩니다.

MS 계정으로 로그인 하면 정품 인증은 되지만, 정작 중요한 제품키는 확인할 수 없습니다. 윈도우 제품키는 윈도우 상에서 확인할 수 있습니다.

 

윈도우10 제품키 확인

윈도우 제품키 정보는 프로그램 설치 없이 확인할 수 있습니다.

다만 정품 인증이 되어 있는 윈도우 노트북 등의 컴퓨터에서 진행해야 제품키를 확인할 수 있을 것입니다.

윈도우 시디키 정보 확인

cmd에 slmgr /dlv 입력하면 윈도우 라이센스 정보를 확인할 수 있습니다.

하지만 윈도우10에서는 제품키 확인이 안될 것입니다. 부분 제품 키만 표시되고 나머지 시디키는 확인할 수 없습니다.

전체 윈도우 시디키 정보는 다음과 같은 방법으로 확인할 수 있습니다. 윈도우8 및 윈도우7 시디키도 확인할 수 있습니다.

인터넷에 보면 윈도우 시디키 확인 프로그램을 배포하는 사이트들이 있습니다. 이런 프로그램들은 정말 주의해서 사용해야 합니다.

이 글에서 설명하는 윈도우 시디키 정보 확인 방법은 프로그램을 이용하는 것이 아니기 때문에 걱정하지 않아도 됩니다.

 

VBScript 만들고 윈도우10 제품키 확인 하기

메모장에 윈도우10 제품키 확인 소스 코드 붙여 넣고 저장

  1. 마우스 우클릭 메뉴인 컨텍스트 메뉴의 새로 만들기를 이용하여 새 텍스트 문서를 생성합니다.
  2. 윈도우10 제품키 확인 소스를 클립보드로 복사합니다.
  3. 복사한 소스를 텍스트 문서에 붙여 넣은 후 저장합니다.

윈도우10 제품키 확인 소스

Option Explicit  

Dim objshell,path,DigitalID, Result  
Set objshell = CreateObject("WScript.Shell")
'Set registry key path
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
'Registry key value
DigitalID = objshell.RegRead(Path & "DigitalProductId")
Dim ProductName,ProductID,ProductKey,ProductData
'Get ProductName, ProductID, ProductKey
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName")
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID")
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)  
ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey
'Show messbox if save to a file  
If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then
  Save ProductData  
End If



'Convert binary to chars
Function ConvertToKey(Key)
        Const KeyOffset = 52
        Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
        'Check if OS is Windows 8
        isWin8 = (Key(66) \ 6) And 1
        Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
        i = 24
        Maps = "BCDFGHJKMPQRTVWXY2346789"
        Do
                  Current= 0
           j = 14
           Do
              Current = Current* 256
              Current = Key(j + KeyOffset) + Current
              Key(j + KeyOffset) = (Current \ 24)
              Current=Current Mod 24
               j = j -1
           Loop While j >= 0
           i = i -1
           KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
           Last = Current
        Loop While i >= 0  
        
        If (isWin8 = 1) Then
           keypart1 = Mid(KeyOutput, 2, Last)
           insert = "N"
           KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
           If Last = 0 Then KeyOutput = insert & KeyOutput
        End If        
        

        ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)
   
        
End Function
'Save data to a file
Function Save(Data)
        Dim fso, fName, txt,objshell,UserName
        Set objshell = CreateObject("wscript.shell")
        'Get current user name  
        UserName = objshell.ExpandEnvironmentStrings("%UserName%")  
        'Create a text file on desktop  
        fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt"
        Set fso = CreateObject("Scripting.FileSystemObject")
        Set txt = fso.CreateTextFile(fName)
        txt.Writeline Data
        txt.Close
End Function

.txt 확장자를 .vbs로 변경

  1. 텍스트 문서의 확장자(.txt)를 .vbs로 변경합니다.
    • 이 때 파일 이름은 상관 없습니다. 윈도우 시디키 정보 확인하기 등 구분하기 쉬운 이름으로 설정합니다.
  1. 확장자를 변경한 Windows 10 product key view.vbs 문서를 실행 시킵니다.

윈도우10 제품키 확인

BackUp Windows Key Information 창이 열리면 윈도우10 제품키 등을 확인할 수 있습니다. 창 이름은 원하는 것으로 변경해도 됩니다.

윈도우10 제품키 확인 소스

만들어 놓은 파일 버리기 아까워 첨부할까 싶었는데요. 한 두 푼 하는 것도 아니고 비싼 윈도우10 시디키 확인 하는 것이니 안전을 위해 직접 만들어서 사용하세요. 직접 만들어 사용하면 소스 코드의 위변조 문제도 발생하지 않습니다.

만약 윈도우10 제품키 확인 소스 코드가 보이지 않거나, 복사가 불가능할 경우에는 링크를 이용하여 구글 문서(BackUp Windows Key Information)에서 확인 하시기 바랍니다.

위의 제품키 확인 소스는 언제든 삭제 또는 제거 될 수 있습니다. 해당 소스 코드는 구글 문서를 아이프레임으로 삽입한 것이기 때문에 구글 드라이브에 저장되어 있는 원본 파일을 실수로 지우면 위 소스 파일도 사라집니다.

추천하는 방법은 아니지만 프로그램을 이용하면 보다 손쉽게 컴퓨터에 설치된 윈도우 시디키 확인 작업이 가능합니다. 프로그램을 실행 시키면 윈도우 Product Key 정보를 확인할 수 있습니다.

댓글 작성하기